100 ' *********************************

110 ' * IBM PC BASIC   VERSION A3.30  *

120 ' * FILE NAME "LS"                *

130 ' * LINE-OF-SIGHT PROPAGATION     *

140 ' * 1987/10                I.KATO *

150 ' *********************************

160 KEY OFF:CLS:SCREEN 9

170 COLOR 14

180 DIM Y(100)

190 LOCATE 1,1:PRINT "[ITEM 3]                 LINE-OF-SIGHT PROPAGATION ":PRINT    :COLOR 7

200 PRINT "When radio waves propagate over the earth, both direct and ground reflected     waves should be considered."

210 GOSUB 1000:GOSUB 2000

220 LOCATE 5,1:PRINT "In this case, the received power can be treated"

230 PRINT "as the vector sum of the two waves which may be"

240 PRINT "considered in free space.":PRINT

250 PRINT "This resultant received power varies as either "

260 PRINT "the transmitting or the receiving point varies.":PRINT

270 PRINT "When the receiving antenna is varied in height,"

280 PRINT "the variation of the received power shows"

290 PRINT "the height pattern on a vertical plane.":PRINT

300 PRINT "In case the curvature of the earth is considered,"

310 PRINT "the same treatment as on a plane earth can be "

320 PRINT "performed by introducing the tangental plane at"

330 PRINT "the reflection point."

340 COLOR 6:LOCATE 23,18:PRINT "----- menu: Hit space key -----"

350 COLOR 7:Q$=INKEY$:IF Q$<>" " THEN 350

370 SCREEN 0:CLS:RUN "ME"

1000 ' ******************

1010 ' *  graph sub(1)  *

1020 ' ******************

1030 YW=INT(50*50/12.74*5)

1040 ' reflection

1050 WINDOW SCREEN(0,-YW)-(100,0)

1060 VIEW(400,56)-(600,133),,5

1070 FOR X=0 TO 100

1080   Y=-(100-X)*X/15

1090   IF X=0 THEN PSET(X,Y) ELSE LINE-(X,Y),2

1100   IF X=50 THEN YM=Y

1110 NEXT

1120 PAINT(50,-50),2

1130 LINE(  0,-600)-(10,0),2

1140 LINE(90,0)-(100,-800),2

1150 PAINT( 5,-100),2

1160 PAINT(95,-100),2

1170 LINE( 0,-600)-(100,-800),7

1180 LINE( 0,-600)-( 45,-160),6

1190 LINE(22,-392)-( 18,-470),6

1200 LINE(22,-392)-( 16,-388),6

1210 LINE(45,-160)-(100,-800),6

1220 LINE(82,-592)-( 75,-550),6

1230 LINE(82,-592)-( 78,-496),6

1240 LOCATE 5,74:PRINT "R":LOCATE 6,52:PRINT "T"

1250 COLOR 7:LOCATE 5,58:PRINT "Direct wave"

1260 COLOR 6:LOCATE 8,58:PRINT "Reflected wave"

1270 COLOR 7:RETURN

2000 ' ******************

2010 ' *  graph sub(2)  *

2020 ' ******************

2030 WINDOW SCREEN(-100,0)-(150,120)

2040 VIEW(400,140)-(600,322),,5

2050 FOR I=1 TO 4

2060   L=(I-2)*50

2070   IF I=4 THEN LINE(L,0)-(L,80),4 ELSE LINE(L,0)-(L,80),7,,&H8888

2080 NEXT

2090 FOR I=1 TO 4

2100   L=I*20

2110   LINE(-100,L)-(150,L),7,,&H8888

2120 NEXT

2130 FOR I=.5 TO 0 STEP -.02

2140   X=SIN(I)*150

2150   Y=8-I*16

2160   PSET(X,Y),3

2170 NEXT

2180 FOR I=0 TO 3.09 STEP .02

2190   X=SIN(I)*150

2200   Y=I*7+8

2210   PSET(X,Y),3

2220 NEXT

2230 FOR I=.05 TO 3.04 STEP .02

2240   X=SIN(I)*150*.95

2250   Y=I*7+29.63

2260   PSET(X,Y),3

2270 NEXT

2280 FOR I=.1 TO 2.99 STEP .02

2290   X=SIN(I)*150*.9

2300   Y=I*6+50.91

2310   PSET(X,Y),3

2320 NEXT

2330 FOR I=0 TO .5 STEP .05

2340   X=-SIN(I)*150

2350   Y=I*6+69.85

2360   PSET(X,Y),3

2370 NEXT

2380 LINE(150,19)-(132,75),2

2390 LINE(0,8)-(23,75),2

2410 COLOR 7:LOCATE 11,54:PRINT "ANTENNA"

2420         LOCATE 12,54:PRINT "HEIGHT(m)"

2430 COLOR 4:LOCATE 14,58:PRINT "free space":LOCATE 15,58:PRINT "value ---->"

2450 COLOR 7:FOR I=0 TO 4:LOCATE 19-I*2,51:PRINT USING "##";I*20:NEXT

2460 LOCATE 20,54:PRINT "-12":LOCATE 20,60:PRINT "-8":LOCATE 20,65:PRINT "-4":       LOCATE 20,70:PRINT "0"  :LOCATE 20,74:PRINT "+4"

2480 LOCATE 21,54:PRINT "RELATIVE RECEIVED"

2490 LOCATE 22,54:PRINT "POWER LEVEL(dB)"

2500 RETURN