100 ' *********************************

110 ' * IBM PC BASIC   VERSION A3.30  *

120 ' * FILE NAME "DIFF"              *

130 ' * DIFFRACTION                   *

140 ' * 1987/10                I.KATO *

150 ' *********************************

160 KEY OFF:CLS:SCREEN 9

170 COLOR 14

180 DIM RL(30),VRL(30)

190 LOCATE 1,1:PRINT "[ITEM 6]                     DIFFRACTION":COLOR 7:PRINT

200 PRINT "Electromagnetic radiation energy disperses infinitively into the higher modes ofFresnel zones.  Diffraction is meant by a phenomenon that electromagnetic wave  turns behind an obstacle."

210 PRINT TAB(47)"In the left figure, a microwave"

220 PRINT TAB(47)"beam horizontally advanced towards";

230 PRINT TAB(47)"a vertical half-infinitive"

240 PRINT TAB(47)"obstacle screen."

250 PRINT TAB(47)"While the upper linear edge of"

260 PRINT TAB(47)"screen keeps down sufficiently"

270 PRINT TAB(47)"away from higher order Fersnel"

280 PRINT TAB(47)"Zones,  the field intensity"

290 PRINT TAB(47)"behind the screen almost equals"

300 PRINT TAB(47)"to the free space value.":PRINT

310 PRINT "As the upper edge approaches up to Fresnel Area, the field intensity varies and demonstrates interference effect as shown in the right figure.  Upwards beyond  the first Fresnel Area, the field intensity steeply falls down.  When the edge"

320 PRINT "just crosses the Fresnel Zone centre, the field intensity gets half down (-6 dB)of the free sapce value.  Further up, then the propagation mode reaches pure    diffraction area."

330 GOSUB 1000:GOSUB 2000:COLOR 7

340 COLOR 6:LOCATE 23,40:PRINT "----- menu:  Hit space key -----"

350 COLOR 7:Q$=INKEY$:IF Q$<>" " THEN 350

360 SCREEN 0:CLS:RUN "ME"

1000 ' ***********************

1010 ' *  graph darw sub(1)  *

1020 ' ***********************

1030 WINDOW SCREEN(0,0)-(100,100)

1040 VIEW( 1,84)-(161,224),,5

1050 CIRCLE(50,50),20,7

1060 CIRCLE(50,50),30,7

1070 CIRCLE(50,50),40,7

1080 LINE(0,75)-(100,75),2

1090 PAINT(50,80),2,2

1100 LINE( 0,50)-(100,50),7

1110 LINE(50,50)-( 50,65),7

1120 LINE(50,40)-(90,40),7,,&H8888

1130 LINE(50,30)-(90,30),7,,&H8888

1140 LINE(50,20)-(90,20),7,,&H8888

1150 LINE( 3,50)-( 3,75),7

1160 LOCATE  7, 1:PRINT "pattern of linear edge"

1170 LOCATE 13, 3:PRINT "HC"

1180 LOCATE 12,12:PRINT "R1"

1190 LOCATE 16, 7:PRINT "OBSTACLE"

1200 COLOR 3

1210 LOCATE  8,19:PRINT "m3"

1220 LOCATE  9,19:PRINT "m2"

1230 LOCATE 10,19:PRINT "m1"

1240 RETURN

2000 ' ***********************

2010 ' *  graph darw sub(2)  *

2020 ' ***********************

2030 WINDOW SCREEN(0,0)-(100,100)

2040 VIEW(180,84)-(340,224),,5

2050 LINE(0,30)-(100,30),7

2060 LINE(0,30)-( 10,30),14

2070 N=0

2080 FOR J=1 TO 4

2090   FOR I=1 TO 3.14*2

2100     N=N+1:X=N*1.5+10:Y=J*1.5*SIN(I)+30

2110     IF N=1 THEN PSET(10,30) ELSE LINE-(X,Y),14

2120 NEXT I,J

2130 XM=X:YM=Y

2140 FOR I=1 TO 50

2150   X=I*4+XM

2160   Y=20*LOG(2*3.14159*I^2)/2.3026+YM

2170   IF I=1 THEN PSET(46,28) ELSE LINE-(X,Y),14

2180 NEXT

2190 LINE(0,60)-(100,60),7

2200 LINE(0,90)-(100,90),7

2210 LINE(56,30)-(56,90),7

2220 LINE(44,0)-(44,20),7,,&H8888

2230 LINE(40,0)-(40,20),7,,&H8888

2240 LINE(35,0)-(35,20),7,,&H8888

2250 COLOR 7

2260 LOCATE  7,38:PRINT "power"

2270 LOCATE  8,38:PRINT "ratio"

2280 LOCATE  9,41:PRINT "1.0"

2290 LOCATE 12,41:PRINT "0.5"

2300 LOCATE 15,43:PRINT "0"

2310 COLOR 3

2320 LOCATE  7,32:PRINT "1"

2330 LOCATE  8,31:PRINT "2"

2340 LOCATE  7,30:PRINT "3"

2350 COLOR 2

2360 LOCATE 16,29:PRINT "HC/R1"

2370 LOCATE 15,35:PRINT "1/2"

2380 RETURN