100 ' ********************************

110 ' *  IBM PC BASIC VERSION A3.30  *

120 ' *  FILE NAME "AVA"             *

130 ' *  SHORT TERM FADING           *

140 ' *  1987/10             I.KATO  *

150 ' ********************************

160 KEY OFF:CLS:SCREEN 0

170 COLOR 14

180 DEFDBL A,P,Q

190 DATA "FREQUENCY(GHz)","SPAN DISTANCE(km)","GEOGRAPHICAL FEATURE",                    "REFLECTION LOSS(dB)","A HEIGHT(m)","B HEIGHT(m)"

200 DATA "mountains","plains","sea face","coast"

210 DATA 85,75,60,50,35,20,15,10,5

220 DATA "62.2","75.5","72.8","72.4","72.2","71.5","71.0"

230 FOR I=1 TO 6:READ U$(I):NEXT

240 FOR I=1 TO 4:READ V$(I):NEXT

250 FOR I=1 TO 9:READ ED(I):NEXT

260 FOR I=1 TO 7:READ SN$(I):NEXT

270 LOCATE 1,1:PRINT "[ITEM 19]        DISTRIBUTION OF RECEIVED POWER DURING SHORT TERM FADING":COLOR 7

280 PRINT "The short term fading caused by an irregular profile of refractive index, is    considered to be the result of a combination of a constant wave and multiple    waves whose amplitudes and phases vary at random very rapidly."

290 PRINT "The cumulative distribution of the received power during the period of extremelydeep short term fading is well approximated by the so-called Rayleigh Distribu- ";

300 PRINT "tion, and may be considered to be most severe in practical conditions. For this reason such deep fading names after ";:COLOR 3:PRINT "Rayleigh Fading.":COLOR 7

310 PRINT "Regarding allowable dropout time rate due to such high noise power, the CCIR re-commends the design objective applicable to 2500km length telephone hypothetical";

320 PRINT "reference circuit: the noise power exceeding 1,000,000 pWp unweighted should notexceed more than 0.01% of any month."

330 PRINT "In a practical link design, each repeater section should be distributedly       allocated with allowable dropout time rate in proportion to its hop distance    from the CCIR 0.01% value as follows."

340 COLOR 3:PRINT "  [ Allowable dropout rate = 4*L*10^-9/(one month) :L=relevant distance (km) ]":COLOR 7

350 PRINT "Prediction of the respective time rates can be obtained from the calculation foroccurrence probability of Rayleigh Distribution high noise due to short term    fading."

360 PRINT "The calculation is to be carried out in reference to the assigned time rate     objective shown above. For convenience the following average noise levels( 50%";

370 PRINT "value) are assumed. Incidentally, occurrence probability estimation formulae    have been provided by ECL. Japan."

380 COLOR 6:LOCATE 23,40:PRINT "----- To proceed:  Hit space key -----"

390 COLOR 7:Q$=INKEY$:IF Q$<>" " THEN 390

400 CLS:SCREEN 9:COLOR 14

410 LOCATE  1,1:PRINT "      [RAYLEIGH FADING OCCURRENCE PROBABILITY AND CIRCUIT DROPOUT RATE]":COLOR 3

420 LOCATE  2,1:PRINT "OCCURRENCE PROBABILITY(PR)":COLOR 7

430 LOCATE  3,1:PRINT "PR=(F/4)^1.2*Q*D^3.5"

440 LOCATE  4,1:PRINT "F:frequency(GHz)"

450 LOCATE  5,1:PRINT "D:span distance(km)"

460 LOCATE  6,1:PRINT "Q:propagation coefficient of path"

470 LOCATE  7,1:PRINT "(A) mountains :2.1*10^-9"

480 LOCATE  8,1:PRINT "(B) plains    :5.1*10^-9"

490 LOCATE  9,1:PRINT "(C) sea face  :3.8*10^-7*1/SQR(H)"

500 LOCATE 10,1:PRINT "(D) coast     :3.8*10^-7*1/SQR(H)"

510 LOCATE 11,1:PRINT "              H=(A HEIGHT+B HEIGHT)/2":COLOR 2

520 LOCATE  2,41:PRINT "CIRCUIT DORPOUT RATE":COLOR 7

530 LOCATE  3,41:PRINT "(1) 2*PR*N0/10^6: effective reflection"

540 LOCATE  4,41:PRINT "                  loss more than 10dB"

550 LOCATE  5,41:PRINT "(2) E*PR*N0/10^6: effective reflection"

560 LOCATE  6,41:PRINT "                  loss less than 10dB"

570 LOCATE  7,41:PRINT "(3)      N0/10^6: sea face & span dis-"

580 LOCATE  8,41:PRINT "                  tance more than 50km"

590 LOCATE 10,41:PRINT " N0:thermal noise of object span(pW)"

600 LOCATE 11,41:PRINT " E :coefficient of effective probability":COLOR 4

610 LOCATE 12, 1:PRINT "              S/N(50%) data is based on a standard span (50 km length)":COLOR 7

620 LOCATE 13, 1:PRINT " FREQUENCY BAND    2GHz    4GHz    5GHz     6GHz(L)   6GHz(U)    7GHz    8GHz"

630 LOCATE 14, 1:PRINT " S/N(50%) in dB    62.2    75.5    72.8     72.4      72.2       71.5    71.0"

640 LINE(1,166)-(639,180),7,B:LINE(1,180)-(639,194),7,B

650 FOR I=1 TO 6:LOCATE 15+I:PRINT I" "U$(I):NEXT

660 GOSUB 1030:GOSUB 1150:GOSUB 1240:GOSUB 1360

670 IF NF>2 THEN GOSUB 1450:GOSUB 1540

680 COLOR 6:LOCATE 23,10:PRINT "Do you correct any data  (Y/N) ? ";:Y$=INPUT$(1)

690 IF Y$<>"Y" AND Y$<>"y" AND Y$<>"N" AND Y$<>"n" THEN 680

700 COLOR 7:LOCATE 23,10:PRINT SPC(69)

710 IF Y$="N" OR Y$="n" THEN 2000 ELSE 720

720 COLOR 6:LOCATE 23,10:INPUT "Input item number to be corrected(1-6) ";NO$

730 COLOR 7:LOCATE 23,10:PRINT SPC(69)

740 NO=VAL(NO$):NFM=NF

750 IF NO<1 OR NO>6 THEN 720

760 LOCATE 15+NO,27:PRINT SPC(20)

770 ON NO GOSUB 1030,1150,1240,1360,1450,1540

780 IF NO=3 AND (NFM<3 AND NF>2) THEN GOSUB 1450:GOSUB 1540

790 GOTO 680

1000 ' ********************

1010 ' *  data input sub  *

1020 ' ********************

1030 ' frequency

1040 COLOR 6:LOCATE 16, 1:PRINT 1" "U$(1)

1050 COLOR 6:LOCATE 22,10:PRINT "Input  "U$(1)" BAND (GHz) ( 2,4,5,6,7,8 ) ";:       LINE INPUT X$

1060 FQ=VAL(X$)

1070 IF FQ<>INT(FQ) OR FQ<2 OR FQ=3 OR FQ>8 THEN LOCATE 22,10:PRINT SPC(69):            GOTO 1050

1080 IF FQ=6 THEN 1090 ELSE B$="":GOTO 1110

1090 LOCATE 23,10:INPUT "Input  L(lower band) or U(upper band)  L/U  ";B$

1100 IF B$<>"U" AND B$<>"u" AND B$<>"L" AND B$<>"l" THEN LOCATE 23,10:                  PRINT SPC(69):GOTO 1090

1110 COLOR 7:FOR I=22 TO 23:LOCATE I,10:PRINT SPC(69):NEXT

1120 LOCATE 16,32:PRINT USING "##";FQ;:PRINT B$

1130 LOCATE 16, 1:PRINT 1" "U$(1)

1140 RETURN

1150 ' span distance

1160 COLOR 6:LOCATE 17, 1:PRINT 2" "U$(2)

1170 COLOR 6:LOCATE 23,10:PRINT "Input  "U$(2)"  ";:LINE INPUT X$

1180 COLOR 7:LOCATE 23,10:PRINT SPC(69)

1190 D=VAL(X$)

1200 IF D<1 OR D>100 THEN 1170

1210 LOCATE 17,31:PRINT USING "###.#";D

1220 LOCATE 17, 1:PRINT 2" "U$(2)

1230 RETURN

1240 ' feature

1250 COLOR 6:LOCATE 18, 1:PRINT 3" "U$(3)

1260 COLOR 6:LOCATE 23,10:PRINT "Input  "U$(3)" (A,B,C,D) of path  ";:               LINE INPUT X$

1270 COLOR 7:LOCATE 23,10:PRINT SPC(69)

1280 NF=ASC(X$)

1290 IF NF<65 OR (NF>68 AND NF<97) OR NF>100 THEN 1260

1300 IF NF<69 THEN NF=NF-64

1310 IF NF>68 THEN NF=NF-96

1320 LL=LEN(V$(NF))

1330 LOCATE 18,36-LL:PRINT V$(NF)

1340 LOCATE 18, 1:PRINT 3" "U$(3)

1350 RETURN

1360 ' reflection loss

1370 COLOR 6:LOCATE 19, 1:PRINT 4" "U$(4)

1380 COLOR 6:LOCATE 23,10:PRINT "Input  TOTAL "U$(4)" of path ";:                    LINE INPUT X$

1390 COLOR 7:LOCATE 23,10:PRINT SPC(69)

1400 RLF=VAL(X$)

1410 IF RLF>100 THEN 1380

1420 LOCATE 19,32:PRINT USING "##.#";RLF

1430 LOCATE 19, 1:PRINT 4" "U$(4)

1440 RETURN

1450 ' A height

1460 COLOR 6:LOCATE 20, 1:PRINT 5" "U$(5)

1470 COLOR 6:LOCATE 23,10:PRINT "Input  "U$(5)"  ";:LINE INPUT X$

1480 COLOR 7:LOCATE 23,10:PRINT SPC(69)

1490 H1=VAL(X$)

1500 IF H1<1 THEN 1470

1510 LOCATE 20,29:PRINT USING "#,###.#";H1

1520 LOCATE 20, 1:PRINT 5" "U$(5)

1530 RETURN

1540 ' B height

1550 COLOR 6:LOCATE 21, 1:PRINT 6" "U$(6)

1560 COLOR 6:LOCATE 23,10:PRINT "Input  "U$(6)"  ";:LINE INPUT X$

1570 COLOR 7:LOCATE 23,10:PRINT SPC(69)

1580 H2=VAL(X$)

1590 IF H2<1 THEN 1560

1600 LOCATE 21,29:PRINT USING "#,###.#";H2

1610 LOCATE 21, 1:PRINT 6" "U$(6)

1620 RETURN

2000 ' *****************

2010 ' *  calculation  *

2020 ' *****************

2030 H=(H1+H2)/2

2040 IF NF=1   THEN Q=2.1*10^-9

2050 IF NF=2   THEN Q=5.1*10^-9

2060 IF NF>2   THEN Q=3.8*10^-7*1/SQR(H)

2070 PR=(FQ/4)^1.2*Q*D^3.5

2080 ' tharmal noise

2090 IF FQ=2 THEN SN=VAL(SN$(1))

2100 IF FQ=4 THEN SN=VAL(SN$(2))

2110 IF FQ=5 THEN SN=VAL(SN$(3))

2120 IF (FQ=6 AND B$="L") OR (FQ=6 AND B$="l") THEN SN=VAL(SN$(4))

2130 IF (FQ=6 AND B$="U") OR (FQ=6 AND B$="u") THEN SN=VAL(SN$(5))

2140 IF FQ=7 THEN SN=VAL(SN$(6))

2150 IF FQ=8 THEN SN=VAL(SN$(7))

2160 SN=SN+20*LOG(50/D)/2.3026

2170 N0=10^((90-SN)/10)

2180 ' CCIR

2190 AC=4*D*10^-9

2200 ' equivalent Q

2210 NO=INT(RLF)

2220 IF NO>9 THEN E=1 ELSE E=ED(NO)

2230 IF D>=50   AND NF>2 THEN AV=N0/10^6     :GOTO 2260

2240 IF RLF>=10          THEN AV=2*PR*N0/10^6:GOTO 2260

2250 IF RLF<10           THEN AV=E*PR*N0/10^6

2260 COLOR 3

2270 LOCATE 16,39:PRINT USING "OCCURRENCE PROBABILITY(month)####.##*10^-4";PR*10^4

2280 COLOR 2

2290 LOCATE 17,39:PRINT USING "CIRCUIT DROPOUT RATE(month)  ####.##*10^-7";AV*10^7

2300 COLOR 5

2310 LOCATE 18,39:PRINT USING "CCIR REC.393-4      (month)  ####.##*10^-7";AC*10^7

2320 COLOR 14:IF AV<=AC THEN 2330 ELSE 2340

2330 LOCATE 19,39:PRINT "This path meets the standards.":                            LOCATE 20,39:PRINT "Space diversity is not considered":                         LOCATE 21,39:PRINT "necessary.":GOTO 2450

2340 LOCATE 19,39:PRINT "This path does not meet the standards.":                    LOCATE 20,39:PRINT "Space diversity will be required.":                         LOCATE 21,39:PRINT "Re-examine after completion of calculation"

2350 LOCATE 22,39:PRINT "over the whole route !"

2360 '

2450 COLOR 6:LOCATE 23,10:PRINT "Do you continue this work (Y/N) ? ";:Y$=INPUT$(1)

2460 IF Y$<>"Y" AND Y$<>"y" AND Y$<>"N" AND Y$<>"n" THEN 2450

2470 COLOR 7:LOCATE 23,10:PRINT SPC(69)

2480 IF Y$="Y" OR Y$="y" THEN 400

2490 CLS:SCREEN 0:RUN "ME"