100 ' **********************************

110 ' *   IBM PC BASIC VERSION A3.30   *

120 ' *   FILE NAME "ANTSEL"           *

130 ' *   ANTENNA DIRECTIVITY          *

140 ' *   1987/10             I.KATO   *

150 ' **********************************

160 KEY OFF:CLS:SCREEN 9

170 COLOR 14

180 DIM S0(59),S1(59),VS0(59),VS1(59),W$(51,1)

190 DATA " 0","  0",".1"," .5",".2"," .7.5",".3","1,0",".4","1.5",".5","2.0",              ".6","2.5",".7","3.0",".8","4.0",".9","5.0","1.0","5.5"

200 DATA "1.1","6.5","1.2","8.0","1.3","9.5","1.4","10.5","1.5","11.5",                  "1.6","13 ","1.7","14" ,"1.8","15" ,"1.9","16"  ,"2.0","17"

210 DATA "2,1","17.5","2.2","18.0","2.3","18.5","2.4","19.0","2.5","19.4",               "2.6","19.8","2.7","20.2","2.8","20.6","2.9","21.0","3.0","21.4"

220 DATA "3.1","21.6","3.2","21.8","3.3","22.0","3.4","22.2","3.5","22.4",               "3.6","22.6","3.7","22.8","3.8","23.0","3.9","23.2","4.0","23.4"

230 DATA "4.1","23.5","4.2","23.5","4.3","23.5","4.4","23.5","4.5","23.5",               "4.6","23.5","4.7","23.5","4.8","23.5","4.9","23.5","5.0","23.5"

240 FOR J=1 TO 51:FOR I=0 TO 1:READ W$(J,I):NEXT I,J

250 LOCATE 1,1:PRINT "[ITEM 15]                ANTENNA DIRECTIVITY ":COLOR 7

260 PRINT "All waves originating at its focal point and reflected from a parabolic surface will reach at a distant point along the axis with the same phase, and produce   as much strong signal as antenna directive gain."

270 PRINT "In directions other than along the axis the path lengths for the various        reflections will differ, and so these waves tend to cancel one another."

280 PRINT "This is recognized as, an attenuation effect from the antenna main lobe, the    magnitude of which(i,e. differential directivity) contributes to the suppressionof reflected and interfering waves."

290 PRINT "Given below is an example of palabolic antenna directivity with 4m diameter in  4GHz band."

300 '

310 OPEN "ASWP4" FOR INPUT AS #1

320 INPUT #1,G:FOR I=0 TO 59:INPUT #1,S0(I),S1(I):NEXT:CLOSE

330 GOSUB 1000

340 LOCATE 12,41:PRINT "Various values of antenna directivity"

350 LOCATE 13,41:PRINT "for different frequency bands are "

360 LOCATE 14,41:PRINT "stored in data file for the use of"

370 LOCATE 15,41:PRINT "the following calculations."

380 LOCATE 17,41:PRINT "Ridge diffraction loss (Items 10,23)"

390 LOCATE 18,41:PRINT "Interference           (Items 24-26)"

400 COLOR 6:LOCATE 23,40:PRINT "----- menu:  Hit space key -----"

410 COLOR 7:Q$=INKEY$:IF Q$<>" " THEN 410

420 CLS:SCREEN 0:RUN "ME"

1000 ' --------------------

1010 ' *  graph draw sub  *

1020 ' --------------------

1030 WINDOW SCREEN(0,0)-(120,60)

1040 VIEW(100,147)-(300,322),,5

1050 LINE(60,0)-(60,60),7

1060 FOR I=1 TO 51

1070   IF I=1  THEN PSET(60,0) ELSE LINE-(60-I,VAL(W$(I,1))),3

1080   IF I=51 THEN LS=VAL(W$(51,1))

1090 NEXT

1100 FOR I=5 TO 59

1110   IF I=0 THEN POINT(60,LS) ELSE LINE-(60+I,S0(I)),3

1120 NEXT

1130 FOR I=0 TO 50 STEP 10:LINE(60-I,0)-(60-I,LS),7,,&H8888:NEXT

1140 FOR I=0 TO 50 STEP 10:LINE(60+I,25)-(60+I,60),7,,&H8888:NEXT

1150 FOR I=5 TO LS STEP  5:LINE(0,I)-(60,I),7,,&H8888:NEXT

1160 FOR I=25 TO 60 STEP 5:LINE(60,I)-(120,I),7,,&H8888:NEXT

1170 COLOR 7

1180 LOCATE 17,15:PRINT "5 4 3 2 1 0"

1190 LOCATE 17,27:PRINT "10  30  50"

1200 LOCATE 18,17:PRINT "degree":LOCATE 18,31:PRINT "degree"

1210 COLOR 3

1220 FOR I=1 TO 5

1230   IF I=3 THEN 1250

1240   LOCATE 13+(I-1)*2,25:PRINT I*10

1250 NEXT

1260 FOR I=1 TO 2:LOCATE 12+(I-1)*11,27:PRINT "loss in dB":NEXT

1270 COLOR 7:RETURN